<< Retour au sommaire

 

L’afficheur virtuel

 

 

 

Table des matières

  1. Introduction ;
  2. Ce qu’il faut savoir ;
  3. Les fonctions ;
  4. Exemple 1 ;
  5. Exemple 2 ;
  6. Liens dans l’afficheur virtuel ;
  7. Exemple 3. 

 

Introduction

 

L’afficheur virtuel de JAWS est une fonctionnalité qui permet d’afficher à l’écran une page d’aide à la demande de l’utilisateur.

 

Bien souvent, JAWS disposent d’ores et déjà de pages d’aides qui peuvent être affichées à l’écran, soit par le raccourci Insère +H, soit par le raccourci Insère +F1 ou le raccourci Insère +F1 2 fois.

La différence entre ces 3 raccourcis et qu’ils n’affichent pas d’aide portant sur les mêmes aspects :

  1. Insère +H, affiche de l’aide sur les scripts de l’application active ;
  2. Insère +W, affiche de l’aide sur les raccourcis clavier de l’application active ;
  3. Insère +F1, affiche de l’aide sur l’objet ayant la prise de focus ;
  4. Insère +F1 2 fois, affiche une aide générale ;
  5. Insère +CTRL +F1, affiche les informations techniques de la fenêtre courante.

 

Les informations affichées dans l’afficheur virtuel sont au format HTML.

Une fois lue, vous pouvez refermer la page en pressant la touche « Échappement ».

 

JAWS permet d’activer ou de désactiver l’affichage virtuel, mais par défaut, il est activé…

Pour activer ou désactiver cette fonctionnalité, allez dans :

Insère +J, « Options » puis « Options de base ».

 

Par contre, lorsque l’afficheur virtuel est désactivé, les informations sont lues et la page est aussitôt refermée.

-         Impossible, dans ce cas-là, de relire tranquillement l’aide avec vos raccourcis habituels de lecture…

 


Ce qu’il faut savoir

 

Pour utiliser correctement l’afficheur virtuel, nous devons manipuler un composant mémoire appelé « le buffer ».

« Le buffer » est une mémoire spécifique dans laquelle on peut accumuler des informations temporairement, et ce, en attendant un traitement tel que l’affichage à l’écran, l’impression etc.

 

Eh bien, la fonctionnalité de « l’afficheur virtuel » de JAWS permet d’accumuler des informations dans le buffer et on peut en déclencher l’affichage à tout moment dans une page d’aide au format HTML.

 

Les fonctions

 

UserBufferIsActive ()

Activer le buffer.

 

UserBufferClear ()

Effacer le contenu du buffer.

 

UserBufferAddText (« le texte »)

-         Le texte doit être entre guillemets sauf s’il s’agit d’une variable…

-         Ajouter du texte dans le buffer.

 

UserBufferActivate ()

Affichage du buffer dans l’afficheur virtuel.

 

Remarque :

 

Exemple 1

 

Dans le bloc notes, nous allons créer une aide qui affichera pas grand-chose depuis le raccourci clavier Insère +H.

 

Script AideBlocNotes ()

 

; Activation de l'afficheur virtuel

UserBufferIsActive ()

 

; Vide le buffer

UserBufferClear ()

 

; Affectation du texte de l'aide dans le buffer

UserBufferAddText ("Le bloc notes utilise les raccourcis de JAWS habituels")

UserBufferAddText ("N'ayez donc aucune crainte !")

 

; Affichage du buffer

UserBufferActivate ()

 

EndScript

 


Exemple 2

 

Ici, nous allons demander à l’utilisateur son prénom, et ensuite, par l’intermédiaire du raccourci clavier CTRL +F1, nous allons afficher un message d’aide en affichant également le prénom !

 

Script AideBlocNotes ()

 

; Déclaration de la variable qui contiendra le prénom

Var String Prenom

 

; Demande à l'utilisateur son prénom

If InputBox ("Quel est ton prénom ? ","Identification",Prenom) Then

  ; L'utilisateur s'est bien identifié

 

  ; Activation de l'afficheur virtuel

  UserBufferIsActive ()

 

  ; Vide le buffer

  UserBufferClear ()

 

  ; Affichage d'un message d'accueil dans le buffer

  UserBufferAddText ("Bonjour "+Prenom+", sois le bienvenue")

 

  ; Affectation du texte de l'aide dans le buffer

  UserBufferAddText ("Le bloc notes utilise les raccourcis de JAWS habituels")

  UserBufferAddText ("N'aie donc aucune crainte !")

 

  ; Affichage du buffer

  UserBufferActivate ()

Else

  ; L'utilisateur n'a pas inscrit son prénom

  MessageBox ("Désolé, au revoir l'inconnu !")

EndIf

 

EndScript

 


Liens dans l’afficheur virtuel

 

Il est possible d’afficher des liens hypertextes dans l’afficheur virtuel.

Pour ce faire, nous devons renseigner 2 paramètres de plus…

 

La syntaxe :

UserBufferAddText ("Texte","Fonction","Lien")

 

La description :

"Texte", Il s'agit du texte du lien à afficher dans la fenêtre virtuelle ;

"Fonction", Il s'agit de la fonction qui sera exécutée lorsque le lien sera activé ;

"Lien", il s'agit du texte du lien qui sera affiché dans la liste des liens activable depuis le raccourci clavier Insert +F7.

 

Remarque :

Tous les autres paramètres ignorés dans ce manuel sont dédiés au formatage, propriétés de la police de caractères et du paragraphe.


Exemple 3

 

Voici un script intitulé « Aide », il affiche une page d’informations techniques sur WORD.

Cette page affiche un lien permettant d’accéder à une liste de raccourcis clavier, la fonction qui est exécutée s’intitule « LaSuite ».

 

Script Aide ()

 

; Activation du buffer

UserBufferIsActive ()

; Réinitialisation du buffer

UserBufferClear ()

 

; Affectation de texte dans le buffer

UserBufferAddText ("Aide pour WORD 2010")

UserBufferAddText ("Traitement de texte de Microsoft")

UserBufferAddText ("Version pack office 2010 standard")

 

; Création d'un lien qui exécutera la fonction intitulée "la suite"

UserBufferAddText ("Pour obtenir de l'aide cliquez ici","LaSuite()","Suivant")

 

; Affichage du buffer dans la fenêtre virtuelle

UserBufferActivate ()

 

EndScript

 

Void Function LaSuite ()

 

; Réinitialisation du buffer

UserBufferClear ()

 

; Affectation du nouveau texte dans le buffer

UserBufferAddText ("Liste des raccourcis clavier pour WORD")

UserBufferAddText ("CTRL +S, enregistrer le document ;")

UserBufferAddText ("CTRL +O, Ouvrir un document ;")

UserBufferAddText ("CTRL +N, Créer un nouveau document vierge.")

 

; Affichage du buffer dans la fenêtre virtuelle

UserBufferActivate ()

EndFunction

 

Philippe BOULANGER