<< Retour au sommaire

 

Les variables de type « tableau »

 

 

Table des matières

1.      Qu’est-ce que c’est ?

2.      La dimension du tableau ;

3.      Les types de tableaux.

 

Qu’est-ce que c’est ?

 

Une variable de type « tableau » est une variable dans laquelle nous pouvons stocker un nombre défini de données, tandis que la variable classique ne peut stocker qu’une seule donnée.

 

La syntaxe pour un tableau de type « chaîne de caractères », donc de type « string » :

Var StringArray MonTableau;

Let MonTableau = new StringArray[5];

-         Dans cette déclaration, nous avons défini 5 emplacements de données pour le tableau qui s’intitule « MonTableau ».

Ultérieurement, nous pourrons donc stocker dans « MonTableau » 5 données de type « String ».

Cette opération est dite bien sûr « affectation », et nous devrons placer entre crochets la position de l’emplacement du tableau vers laquelle la donnée doit être stockée, c’est « l’indice » du tableau…

 

Let MonTableau[1] = "DUPONT";

Let MonTableau[2] = "DURAN";

Let MonTableau[3] = "VERNE";

Let MonTableau[4] = "DE MONACO";

Let MonTableau[5] = "MARTIN";

 

Vous avez donc compris que nous avons utilisé l’indice (3 » pour mémoriser « VERNE ».

Par conséquent, nous pouvons demander à JAWS de lire « VERNE » de la façon suivante :

SayString (MonTableau[3])

 

Voici un exemple qui mémorise dans « MonTableau » les 5 premiers mots d’une ligne.

Pour compliquer un peu, nous allons utiliser un compteur de type « Int » qui jouera le rôle d’indices de tableau !

 

Script DebutDeLigne ()

; Déclaration de MonTableau

Var StringArray MonTableau,

; Déclaration du compteur

Int compteur

; Définition de la taille du tableau

Let MonTableau = new StringArray[5]

; Mémorisation des 5 premiers mots de la ligne

For compteur = 1 To 5

 ; Pour chaque itération de la boucle, mémorisation du mot courant et passage au mot suivant

 Let MonTableau[compteur] = GetWord ()

 NextWord ()

EndFor

; Lecture des 5 premiers mots

For compteur = 1 To 5

 ; A chaque itération de la boucle, lecture du mot courant dans le tableau

 SayString (MonTableau[compteur])

EndFor

EndScript

 

Remarque :

-         Dans le cadre de l’utilisation d’un tableau dans une boucle, un compteur joue souvent le rôle d’indice car il est incrémenté à chaque itération.

 

La dimension du tableau

 

Dans le chapitre précédent, nous avons utilisé un tableau en une seule dimension.

Afin de mieux comprendre ce type de variable, imaginez qu’il s’agît d’une variable divisée en un certain nombre de cases alignées sur une seule rangée.

C’est un tableau en une seule dimension !

En effet, puisque notre variable à la structure d’un tableau, nous pourrions aisément prévoir plusieurs rangées !

En résumé, notre variable aurait la même structure qu’un tableau affiché à l’écran…

Une variable contenant plusieurs rangées, et pour chacune d’entre elle, le même nombre de cellules.

 

Génial ! On pourrait alors maintenant mémoriser le prénom des 5 personnes !

Il suffirait d’utiliser 2 indices, la première désignerait la rangée, et par conséquent, la seconde indice désignerait la cellule, enfin la colonne.

 

On fait un exemple ?

 

Script Essai ()

 

; déclaration du tableau

Var StringArray candidats

; Définition des dimensions

Let candidats = new StringArray [5,2]

; Affectation des prénoms et noms des candidats

Let candidats[1,1] = "Christophe";

Let candidats[1,2] = "DUPONT";

Let candidats[2,1] = "Marcel";

Let candidats[2,2] = "DURAN";

Let candidats[3,1] = "Jules";

Let candidats[3,2] = "VERNE";

Let candidats[4,1] = "Stéphanie";

Let candidats[4,2] = "DE MONACO";

Let candidats[5,1] = "Jacques";

Let candidats[5,2] = "MARTIN";

; Demande à JAWS d'annoncer une certitude !

SayString ("Il est à peu près certain que "+candidats[3,1]+candidats[3,2]+" ne s'est jamais marié avec "+candidats[4,1]+candidats[4,2])

EndScript

 

A l’exécution du script, vous devriez entendre :

« Il est à peu près certain que Jules VERNE ne s’est jamais marié avec Stéphanie DE MONACO ».

 

Remarque :

-         Ce genre de script ne sert strictement à rien ! Mais j’ai décidé d’employer des exemples parlants…

 

Les types de tableaux

 

Il est possible bien entendu de créer des tableaux d’un autre type que le « String », par exemple, voici un tableau de type « INT » :

 

Script essai ()

 

Var IntArray Ages

Let Ages = new IntArray[5]

Let Ages[1] = 28

Let Ages[2] = 56

SayInteger (Ages[2])

SayString ("est le double de ")

SayInteger (Ages[1])

EndScript

 

Philippe BOULANGER